// generate movie reviews
//
// this script requires the dada engine, see:
// http://dev.null.org/dadaengine/

#include <stdmap.pbi>


// generate 30 entries when the script is invoked
thirtyentries:
	entry entry entry entry entry
	entry entry entry entry entry
	entry entry entry entry entry
	entry entry entry entry entry
	entry entry entry entry entry
	entry entry entry entry entry
;

// transformations
pluralise:
        ".*y$" -> "y$"/"ies"
        ".*s$" -> "$"/"es"
        ".*" -> "$"/"s"
;

add-indef:
        "^simply [aeiou].*" -> "^simply"/"simply an"
        "^simply.*" ->  "^simply"/"simply a"
        "^just [aeiou].*" -> "^just"/"just an"
        "^just.*" -> "^just"/"just a"
        "^[aeiou].*" -> "^"/"an "
        "^.*" ->  "^"/"a "
;

super:
        "^gut" -> "^gut"/"most gut-wrenching"
        ".*" -> "^"/"most "
;

// rules
entry:
	  "\n" short-entry "\n"
	| "\n" long-entry "\n"
	| "\n" long-entry "\n"
	| "\n" long-entry "\n"
;


short-entry:
	  bold-statement>upcase-first ". "
	| bold-statement>upcase-first ". "
	| bold-statement>upcase-first ". "
	| introduction bold-statement>upcase-first ". "
	| simple-statement>upcase-first ". "
	| simple-statement>upcase-first ". " simple-statement>upcase-first ". "
	| ["Simply put, " | "In short, " | "To "["make" | "keep"] " things short, "]
	  [bold-statement |  simple-statement] ". " 
;

long-entry:
		[introduction | "" | ""]
		short-statement>upcase-first ". "
		statement>upcase-first ". "
		[statement>upcase-first ". " | short-statement>upcase-first ". " | ""]
		[simple-statement>upcase-first ". " | "" | ""]
	|	[introduction | "" | ""]
		[short-statement>upcase-first ". " | statement>upcase-first ". "]
		[short-statement>upcase-first ". " | statement>upcase-first ". "]
		[simple-statement>upcase-first ". " | "" | ""]
	|	simple-statement>upcase-first ".<br />"
		[short-statement>upcase-first ". " | statement>upcase-first ".<br />"]
		[short-statement>upcase-first ". " | statement>upcase-first ". "]
		[statement>upcase-first ". " | ""]
		[short-statement>upcase-first ". " | statement>upcase-first ". " | ""]
;  

introduction:
	  expectation>upcase-first ". "
	| expectation>upcase-first ". "
	| reason>upcase-first ". "
	| expectation>upcase-first " but " movie " " contrary-statement ". "
;

statement:
	  short-statement ", " nevertheless " it is " [somewhat | ""] " " flawed-adjective
	| though " " short-statement ", " my-opinion
	| "not " ["very " | ""] entertaining-adjective ", " nevertheless " " short-statement
	| "the " big-concrete-noun  " " contrary-statement
	| though " " short-statement ", it " contrary-statement
	| "it " contrary-statement ", " nevertheless " " short-statement
	| short-statement ", " nevertheless " " director-statement
	| short-statement ", " nevertheless " the " aspect-noun " " contrary-statement
	| short-statement ", " maybe " the " vague-adjective>super " " concrete-noun " " released
	| [ director-statement | movie " " contrary-statement ]
;

bold-statement:
	  [maybe " "| ""] "the most " interesting-adjective " " concrete-noun " " released
	| some-adjective>add-indef ", " adverb " " some-adjective ", " some-adjective " " bold-noun
	| some-adjective " and " some-adjective " " bold-part
	| entertaining-adjective " but " flawed-adjective " " bold-part
	| "it " ["all " | ""] ["adds up to " | "comes down to "]
	  ["one " big-adjective | big-adjective>add-indef]
	  [", " flawed-adjective| ""]
	  [" - " nevertheless " " interesting-adjective " - " | " " ]
	  bold-noun
	| movie " is " flawed-adjective>add-indef " " bold-noun
	| movie " is " superlative
	| "it is " superlative>add-indef " " concrete-noun
	| "this " flawed-adjective " " concrete-noun " is "  bold-noun>add-indef
	| "what " flawed-adjective>add-indef " "  bold-noun
	| expression>add-indef
	| interesting-adjective>add-indef " " expression
;

released:
	["to hit theaters" | "at the " ["film" | ""] "festival"| "in Rotterdam" | "to hit the " ["big "|""] "screen"]
	[" this year" | " since a long time" | " lately" | ""]
;

director-statement:
	  " %DIRECTOR% makes it " interesting-adjective [" and " interesting-adjective]
	| " %DIRECTOR% " ["turns it into " | "manages to " ["transform" | "turn"] " it into "]
		["something " interesting-adjective [" and " interesting-adjective|""] | vague-thing>add-indef ]
	| " %DIRECTOR%'s direction " 
		["is " flawed-adjective 
		| "will not be to everyone's taste" 
		| "isn't " interesting-adjective " for everyone"]
;

contrary-statement:
	  [" becomes " | " is in the end " | " actually was "]
	  [ flawed-adjective ["" | " and " flawed-adjective] |
	    flawed-adjective>add-indef " " concrete-noun]
	| " is most of the time "  pointless-adjective
	| [" does not " | " doesn't "]
		["produce " |"result in " | "make "]
		good-adjective>add-indef " " concrete-noun
	| " is " ["utterly " | "totally "]  flawed-adjective [" with its " vague-thing | ""]
	| suffer-statement
;

simple-statement:
	  interesting-adjective ", " [interesting-adjective | entertaining-adjective]
	  " and " [interesting-adjective | entertaining-adjective]
	| "more of " interesting-adjective>add-indef " " concrete-noun " than "
	  interesting-adjective>add-indef " " concrete-noun
	| interesting-adjective [" yet " | " but "]  [flawed-adjective | pointless-adjective | flawed-adjective]
	| "a  "["rather " | "very "] interesting-adjective " " concrete-noun
	| expression>add-indef
;

expression:
	  [ "cinematic " | "big " | "tough " | "" | "virtuoso "]
	  [ "letdown" | "slam-dunk" | "ensemble piece" | "achievement"]
	| "must see"
;

short-statement:
	  concrete-noun>add-indef " that " makes-statement-about " " single-vague-noun
	| movie " is " abst-noun>add-indef " of " plural-vague-noun 
	| movie " is " abst-noun2>add-indef " of " plural-vague-noun 
	| movie " is " vague-thing>add-indef with-some
	| movie " " abst-verb " "  vague-thing>add-indef
	| movie " is " concrete-noun>add-indef " full of " single-vague-noun with-some
	| movie " is " interesting-adjective ["" | " and " interesting-adjective] with-some
	| "the " vague-noun>pluralise " of " movie " are " [interesting-adjective | entertaining-adjective]
	| movie " has some " interesting-adjective " " part-noun>pluralise
	| movie " is " simple-statement
	| "the " vague-noun " of " movie " " abst-verb " " single-vague-noun
	| "the " aspect-noun " is " [superlative | good | interesting-adjective] 
	  	["" 
		| " and the " aspect-noun " is " [superlative | good | interesting-adjective] 
		| " as is the " aspect-noun ]
	| level-statement
	| movie " " suffer-statement
;

with-some:
	   " with " ["a few " | "some " | "lots of " ] some-adjective " "
	   [plural-vague-noun | part-noun>pluralise]
	 | "" | ""
;

level-statement:
	  movie " works on " ["so " | ""] "many " ["different "| ""] "levels"
	| movie " works on " vague-adjective>add-indef " level"
	| movie " works on " vague-adjective>add-indef " level"
	| movie " works on both " vague-adjective>add-indef [" level" | ""]
	  " and " ["on " | ""] vague-adjective>add-indef " level"
	| movie " works " ["more" | "better"] " on " vague-adjective>add-indef [" level" | ""]
	  " than on " vague-adjective>add-indef " level"
	| movie " works equally " ["well" | "fine"] " on " vague-adjective>add-indef
	  [" level" | ""] " and " ["on " | ""] vague-adjective>add-indef " level"
;


suffer-statement:
	  "ultimately " suffers
	| suffers " in the end"
	| suffers " in the final " ["reel" | part-noun | part-noun>pluralise]
	| suffers
	| suffers
;

suffers:
	  "suffers " [adverb " "| " "] "from " [some-adjective>add-indef " " vague-adjective | vague-adjective>add-indef] " imbalance"
	| "suffers " [somewhat " "| " "] "from "
	  [flawed-adjective>add-indef " "  aspect-noun1 | flawed-adjective " " aspect-noun2]
	| "lacks " [vague-adjective|""] " " single-vague-noun
	| "is " [somewhat " "| " "] "flawed by "
	  [flawed-adjective>add-indef " "  aspect-noun1 | flawed-adjective " " aspect-noun2]
	| "fails " ["to deliver"
		| "to transfer " single-vague-noun 
		| "in it's " vague-adjective " " abst-noun 
		| "to meet it's " ["intention" | "potential" | "targets"]]
	| "falls short " ["of " single-vague-noun | "of " vague-noun | "on " plural-vague-noun | ""]
;

expectation:
	  "I had high expectations because " reason
	| reason ", so my expectations were high"
	| reason ", so I wanted to see " [movie | "what "[movie | "the buzz"] " is about"]
	| "my expectations were high"
	| "I expected a " superlative " " concrete-noun " because " reason
	| "Expectations were high since " reason
	| "I expected a lot from this " concrete-noun
;

reason:
	  friend [" who saw the first screening" | ""] " told me " movie " was " superlative
	| "I heard " movie " is " [good | simple-statement]
	| "I heard a lot about this movie"
	| "the festival paper called it " [interesting-adjective>add-indef " " concrete-noun | simple-statement]
	| "the Daily Tiger said '"  short-statement "'"
	| "many people are talking about this movie"
	| friend " already saw it and recommended it"
	| movie [" created" | "generated"] " a lot of buzz" 
		[" at the festival" 
		| " from those who saw it" 
		| " from critics"
		| " from the first screening"
		| " from the filmakers"
		| ""]
	| "I heard a lot of good things about it"
	| "a lot op people recommended it"
	| "it "	["ranks high in the contest"
		| "is listed high on the list"
		| "is in the top 10" 
		| "tops the list"]
	   " " ["of most popular movies" | "for the audience award" | "in the audience survey"]
	| "%DIRECTOR% is one of my favourite directors"
	| "I saw " interesting-adjective>add-indef " interview with %DIRECTOR%"
	| "I love %DIRECTOR%'s " [["previous "| "earlier "| ""] concrete-noun>pluralise | "previous " concrete-noun]
;

my-opinion:
 	  "I can't say " ["it" | movie]  " is " [interesting-adjective | entertaining-adjective] ["" | " or " interesting-adjective]
	| "I didn't find " opinion-object " " [interesting-adjective | entertaining-adjective]
	| "I thought " ["it" | movie] " was " [flawed-adjective | pointless-adjective]
	| "I found " opinion-object " very " [entertaining-adjective | flawed-adjective | interesting-adjective]
;

opinion-object:
	  movie
	| "it"
	| ["all" | "some" | "most" | "a few" ] " " part-noun>pluralise
;

movie:
	  def-article " " concrete-noun
	| def-article " " concrete-noun
	| def-article " " concrete-noun
	| "%MOVIE%"
	| "it"
	| "it"
;

bold-noun:
	  "doodle"
	| "bore"
	| "piece of " bold-part
	| "drag"
	| "waste of " ["time" | "talent" | "money" | "energy" | "film"]
;
	
bold-part:
	  "junk"
	| "fun"
	| "crap"
	| "nonsense"
;

failure-noun:
	  "imbalance"
;

maybe:
	  "maybye"
	| "probably"
	| "perhaps"
	| "arguably"
;

aspect-noun:
	  aspect-noun1
	| aspect-noun2
;

aspect-noun1:
	  "plot"
	| "soundtrack"
	| "script"
	| "idea"
	| "execution"
	| "composition"
	| "structure"
;

aspect-noun2:
	  "cinematography"
	| "lighting"
	| "dialog"
	| "casting"
	| "acting"
	| "filmmaking"
;


big-concrete-noun:
	  interesting-adjective " " concrete-noun
	| adverb " " interesting-adjective " " concrete-noun
	| concrete-noun
;

concrete-noun:
 	  "movie"
	| "movie"
	| "script"
	| "story"
	| "film"
	| "attempt"
	| "tale"
	| "picture"
	| "flick"
	| ["experience" | "project" | "work"]
;

vague-thing:
	  abst-noun " of " single-vague-noun
	| [abst-noun| abst-noun2] " of " plural-vague-noun ["" | "" | " and " plural-vague-noun]
	| [abst-noun| abst-noun2] " of " vague-adjective plural-vague-noun
	| abst-noun " that " makes-statement-about 
		[" all " | " "]
		[ single-vague-noun
		| vague-noun " and " vague-noun
		| some-adjective plural-vague-noun]
;	  

single-vague-noun:
	  "laughter"
	| "zest"
	| "grace"
	| "finesse"
	| "humor"
	| "meditation"
	| "catharsis"
	| "redemption"
	| "innocence"
	| "satisfaction"
	| "guilt"
	| "indulgence"
	| "realism"
	| "loss"
	| "effervescence"
	| "suspense"
	| "cohesion"
	| "consistency"
	| "depth"
	| "sin"
	| vague-adjective " rigor"
;

vague-noun:
	  "emotion"
	| "mood"
	| "effect"
	| "insight"
	| "message"
	| "sacrifice"
	| "style"
	| "layout"
	| "attitude"
	| "motivation"
	| "intention"
;

plural-vague-noun:
	  [ "morals" | "pitfalls" | "stereotypes" | "sparks" | "laughs" | "associations"]
	| vague-noun>pluralise
;

vague-adjective:
	  "emotional"
	| "social"
	| "psychological"
	| "symbolic"
	| "dramatic"
	| "structural"
	| "semantic"
	| "formal"
	| "personal"
	| "cultural"
	| "physical"
	| "political"
	| "subliminal"
	| "visual"
	| "auditory"
	| "gut"
	| "visceral"
	| "certain"
	| "narrative"
	| "intellectual"
	| "erotic"
; 


part-noun:
	  "moment"
	| "part"
	| "scene"
	| "shot"
	| "element"
;

makes-statement-about:
	  "affirms" 
	| "denies" 
	| "reiterates" 
	| "deconstructs"
	| "shows"
	| "obscures"
        | "examines" 
	| "analyses"
	| "concerns"
	| "depicts"
	| ["looks for " | "raises "] ["questions about" | "answers on" | "concerns on"]
;


abst-noun: 
	  "study"
	| "exercise"
	| "exploration"
	| "analysis"
	| "examination"
	| "lesson"
	| "suggestion"
	| "celebration"
;

abst-noun2:
	  "tableau"
	| "melange"
	| "myriad"
	| "kaleidoscope"
;

abst-verb:
	  "resonates"
	| "compels " ["us" | "the audience" | "the viewer" | "viewers"] " to " ["accept" | "examine" | "define"]
	| "brandishes"
	| "emanates"
	| "promotes"
	| "attacks"
	| "evades"
	| "reverberates"
	| "reflects on"
	| "challenges"
	| "is endowed with"
	| makes-statement-about
;

superlative:
	  [ "absolutely " | "just " | "truly " | "simply "] superlative-adjective
	| superlative-adjective
;

superlative-adjective:
	  "great"
	| "excellent"
	| "stunning"
	| "enthralling"
	| "phenomenal"
	| "wonderful"
	| "stellar"
	| "amazing"
	| "terrific"
	| "brilliant"
	| "fabulous"
	| "overwhelming"
	| "gorgeous"
	| "superb"
;

good:
	  ["pretty" | "rather" | "just" | "reasonably"] " " good-adjective
	| good-adjective 
	| good-adjective
;

good-adjective:
	  "good"
	| "fine"
	| "ok"
	| "enjoyable"
	| "pleasant"
	| "nice"
	| "gratifying"
	| "okay"
	| "decent"
	| "cool"
	| "amusing"
	| "entertaining"
;

big-adjective:
	  "big"
	| "large"
	| "long"
	| "slow"
;

some-adjective:
	  interesting-adjective
	| entertaining-adjective
	| flawed-adjective
;

interesting-adjective:
	  "inspirational"
	| "gripping"
	| "emotional"
	| "absorbing"
	| "fascinating"
	| "urgent"
	| "insightful"
	| "authentic"
	| "realistic"
	| "intriguing"
	| "groundbreaking"
	| "evocative"
	| "thought-provoking"
	| "ambitious"
	| "convincing"
	| "visionary"
	| "legitimate"
	| "philosophical"
	| "memorable"
	| "profound"
	| "thoughtful"
	| "perceptive"
	| "substantial"
	| "honest"
	| "magical"
	| "encouraging"
	| "literate"
	| "sensual"
	| "elegaic"
	| "scumptious"
	| "compelling"
	| "haunting"
	| "engrossing"
	| "poignant"
	| "impressive"
	| "remarkable"
	| "spellbinding"
	| "clever"
	| "eloquent"
	| "singular"
	| "unsettling"
	| "perplexing"
	| "outlandish"
	| "whip-smart"
	| "pristine"
	| "atmospheric"
	| "subversive"
	| "shattering"
	| "untarnished"
	| "naturalistic"
	| "caustic"
	| "unimpeachable"
	| "beauty-induced"
	| "smart"
	| "distinctive"
	| "edgy"
	| "impeccable"
	| "bizarre"
	| "intangible"
	| "transparent"
	| "dazzling"
	| "sincere"
;

entertaining-adjective:
	  "entertaining"
	| "buoyant"
	| "invigorating"
	| "engaging"
	| "enjoyable"
	| "exhilarating"
	| "upbeat"
	| "exuberant"
	| "smooth"
	| "slick"
	| "irreverent"
;
	
flawed-adjective:
	  "flawed"
	| "disjointed"
	| "stereotypical"
	| "forgettable"
	| "forced"
	| "painful"
	| "ungainly"
	| "toothless"
	| "superficial"
	| "cliche-driven"
	| "cliche-ridden"
	| "sentimental"
	| "schematic"
	| "predictable"
	| "outrageous"
	| "infantile"
	| "vulgar"
	| "profane"
	| "facile"
	| "overwrought"
	| "frivolous"
	| "cloudy"
	| "old"
	| "schlocky"
	| "languid"
	| "flat"
	| "abominable"
	| "uneventful"
	| "pretentious"
	| "overrated"
;

pointless-adjective:
	  "pointless"	
	| "aimless"
	| "harmless"
;

though:
	  "though"
	| "though"
	| "although"
	| "while"
	| "while"
	| "even if"
	| "as much as"
	| "despite the fact that"
;

nevertheless:
	  "never the less"
	| "but perhaps"
	| "perhaps"
	| "no doubt"
	| "surely"
	| "still"
	| "but still"
	| "but"
	| "however"
	| "albeit"
;

somewhat:
	  "somewhat"
	| "a bit"
	| "actually"
	| "rather"
	| "slightly"
	| "very"
	| "extremely"
;

adverb:  adv-2 | "perhaps " adv-2 | "somewhat "adv-2 | "almost " adv-2;

adv-2:
	  "profoundly"
	| "inherently"
	| "deftly"
	| "tightly"
	| "virtually"
	| "suprisingly"
	| "occasionally"
	| "paradoxically" 
	| "ironically"
	| "astonishingly"
	| "pleasantly"
;

def-article :
	  "the"
	| "the"
	| "the"
	| "this"
;

friend :
	  "Liorah"
	| "Zutman"
	| "Marcel"
	| "Tonio"
;